Google 試算表【SPARKLINE】直接在儲存格建立「迷你圖表」!

Last Updated on 2021 年 11 月 21 日 by 小幫手

How to use SPARKLINE function in Google sheets 封面圖片

Google 試算表的儲存格,除了可以放數字、文字之外,也可以利用「IMAGE」函式來把圖片插入儲存格當中。但其實還有一種東西也可以放進儲存格裡面,那就是用資料繪製出來的「圖表」!只要使用「SPARKLINE」這個函數,就可以在儲存格裡面畫出迷你的小圖表囉!

SPARKLINE 的語法

SPARKLINE 的公式語法為:

=SPARKLINE(data,[options])


第一個引數「Data

就是要建立圖表所需要的資料範圍或陣列。

第二個引數「Options

則是可以決定這個資料要繪製成什麼樣子的圖表,以及用來自訂圖表的「關聯值」。也就是說這邊能設定「折線圖」或是「長條圖」這些圖表的細節,像是大小或顏色之類的;其中顏色的部分可以直接用顏色的英文,也可以使用 16 進位的顏色代碼

Options 這個引數裡的寫法,是要用大括號 {} 來包住裡面的圖表參數設定,每個參數設定之間要用分號 ; 來分開。由於這邊可以設定的參數類型會有點多,我把它們放在文章的最底部,或是前往「文件編輯器說明」了解也可以。


SPARKLINE 實際應用範例

接下來就運用一些圖表跟參數的搭配,試著製作出各種不同類型的圖表吧。

折線圖 line

折線圖是「SPARKLINE」的預設值,所以就算沒有第二個引數「Options」,也可以在儲存格裡繪製出簡易的「折線圖」圖形。

最簡單的 SPARKLINE 公式就是下面這樣,只有資料範圍:

=SPARKLINE(B2:H2)
Sparkline折線圖 line


除了上面最簡單的範例公式之外,你可以開始在第二個引數裡面,添加一些簡單的圖表餐數,來改變圖表的外觀。

例如我可以在「Options」引數裡面添加顏色的參數 color,讓折線圖變成紅色的線:

=SPARKLINE(B2:H2,{"color","red"})
Sparkline紅色折線圖
Sparkline折線圖的顏色,也可以用文字顏色或背景顏色來改變
(折線圖的顏色也可以透過文字或背景顏色來改變)


如果覺得折線圖的線太細的話,可以再加上 linewidth 的參數,這邊要注意的,就是如果出現兩種以上的參數,那每個種參數之間要用分號 ; 來分開它們。公式就類似下面這樣:

=SPARKLINE(B2:H2,{"linewidth",5;"color","red"})
Sparkline折線圖的線寬


除了線條粗細跟顏色可以調整之外,你也可以設定圖表的上下限。

=SPARKLINE(B2:H2,{"ymax",25;"color","red"})
Sparkline折線圖的上限值


aifian APP推薦活動
[ 這 是 APP 推 廣 活 動 廣 告 ]


直條/柱狀圖 column

如果不想使用「折線圖」,就要在「Options」裡面添加 charttype 這個參數,才能轉換為其他的圖表類型。所以「直條圖」的話就是加入「”charttype”,”column”」進去。

=SPARKLINE(B2:H2,{"charttype","column";"color","#FF8000"})
Sparkline直條圖 column


其他圖表會有不同類型的參數可以使用,像是「直條圖」能設定參數來改變最高或最低 Column 的顏色,就像下面這張圖一樣,我透過設定參數,來把最高的 Column 標示為紅色,這樣可以更好比較。

=SPARKLINE(B2:H2,{"charttype","column";"color","#4F4F4F";"highcolor","red"})
Sparkline直條圖設定最高值的顏色


另外它還可以設定參數來繪製中線。

=SPARKLINE(B2:H2,{"charttype","column";"color","brown";"axis",TRUE})
Sparkline直條圖繪製中線


勝負走勢圖 winloss

如果圖表類型設定的是 winloss,它就會變成一種勝負走勢圖,這種圖跟直條圖有點類似,但它只有「正」跟「負」的差別。

=SPARKLINE(B2:H2,{"charttype","winloss";"color","red";"negcolor","green"})
Sparkline勝負走勢圖 winloss



它跟直條圖一樣也有中線的參數可以設定,而中線的顏色也是可以改變的。

=SPARKLINE(B2:H2,{"charttype","winloss";"color","red";"negcolor","green";"axis",TRUE;"axiscolor","black"})
Sparkline勝負走勢圖繪製黑色的中線


堆疊長條圖 bar

第四種圖表就是 bar 堆疊長條圖,長的就像下面這張圖一樣。

=SPARKLINE(B2:H2,{"charttype","bar"})
Sparkline堆疊長條圖 bar


長條圖可以設定的參數會比較少一些,但顏色至少還是可以改變的。

=SPARKLINE(B2:H2,{"charttype","bar";"color1","#0066CC";"color2","#C6A300"})
Sparkline堆疊長條圖改變兩種顏色

另外,SPARKLINE的堆疊長條圖也很適合拿來製作「進度條」,其中的設定技巧可以參考這篇文章:「Google試算表|用SPARKLINE把【進度條】放進儲存格裡! 」


aifian APP推薦活動
[ 這 是 APP 推 廣 活 動 廣 告 ]


SPARKLINE Options 可以設定的參數類型

  • “charttype” 選項是用於定義要繪製的圖表類型,可以用的圖表類型包括:
    • “line”:折線圖(預設值)
    • “bar”:堆疊長條圖。
    • “column”:直條圖。
    • “winloss”:一種特殊的直條圖,可能包含正負兩種輸出結果(就像擲硬幣的正反面)
  • 折線圖
    • “xmin”:設定橫軸的下限值。
    • “xmax”:設定橫軸的上限值。
    • “ymin”:設定縱軸的下限值。
    • “ymax”:設定縱軸的上限值。
    • “color”:設定線條的顏色。
    • “empty”:設定空白儲存格的處理方式(zero/ignore)
    • “nan”:設定如何處理含有「非數字資料」的儲存格(convert/ignore)
    • “rtl”:設定是否以「從右到左」的方向呈現圖表(true 或 false)
    • “linewidth”:設定圖表線條的寬度,數字越大線越粗。
  • 直條(柱狀)圖 & 勝負分析走勢圖:
    • “color”:設定直條圖的顏色。
    • “lowcolor”:設定圖表中最低值的顏色。
    • “highcolor”:設定圖表中最高值的顏色。
    • “firstcolor”:設定第一欄的顏色。
    • “lastcolor”:設定最後一欄的顏色。
    • “negcolor”:設定「所有負值」欄的顏色。
    • “empty”:設定空白儲存格的處理方式。(zero/ignore)
    • “nan”:設定如何處理含有「非數字資料」的儲存格。(convert/ignore)
    • “axis”:定義是否需要繪製某條軸(true/false)
    • “axiscolor”:設定軸線顏色(如果適用)
    • “ymin”:設定用於擴充欄高的自訂下限值(不適用於勝負分析走勢圖)
    • “ymax”:設定用於擴充欄高的自訂上限值(不適用於勝負分析走勢圖)
    • “rtl”:設定是否以從右到左的方向呈現圖表(true/false)
  • 堆疊長條圖
    • “max”:設定橫軸的上限值。
    • “color1”:設定圖表的第一種顏色。
    • “color2”:設定圖表的第二種顏色。
    • “empty”:設定空白儲存格的處理方式(zero/ignore)
    • “nan”:設定如何處理含有非數字資料的儲存格(convert/ignore)
    • “rtl”:設定是否以從右到左的方向呈現圖表(true/false)


結語

看完這一系列的「SPARKLINE」函數操作之後,應該能理解這個函數該怎麼用了吧!「圖表」不管是在 Excel 或是 Google 試算表裡面,都是很好用的分析工具,只是一般插入的圖表都是在儲存格上面,有時候把它放進儲存格裡面會比較方便一些。

Reference:ProductivitySpot文件編輯器說明


延伸閱讀

【Google試算表】文章總列表

Google 試算表|用 SPARKLINE 把【進度條】放進儲存格裡! 

Google 試算表插入圖片可以用【IMAGE函數】4種模式任你選!

Google 試算表如何【插入圖表】?自動生成圖表的方法?

Google 試算表|如何插入公式?公式 12 個【小技巧】都學起來!


aifian APP推薦活動


最後
§ 很感謝你的閱讀 §
如果你喜歡這篇文章的話

→ 歡迎 留言分享

→ 歡迎點下面這張圖來【贊助】支持我!讓我繼續為你創作更多內容!

贊助我一杯咖啡


留言區